4-4.シート編集

今回は、シートの編集として、シートの移動・複製・表示設定について説明します。

シートの移動

Moveメソッド

○構文
Worksheet.Move Before:=/After:=

○処理
指定したワークシートを移動します。

○引数
Before/Afterに既存のSheetオブジェクトを指定すると、指定したシートの前/後に移動します。
Before/Afterを指定しない場合、新規ブックが作成され、そこに移動します。

Sub シートの移動()
    
    '先頭に移動
    Worksheets(2).Move Before:=Worksheets(1)
    '一番最後に移動
    Worksheets(1).Move After:=Worksheets(Worksheets.Count)
    
    '新規ブックに移動
    Worksheets(1).Move
    
    '既存の別ブックに移動
    Workbooks(1).Worksheets(1).Move _
    After:=Workbooks(2).Worksheets(Workbooks(2).Worksheets.Count)
    '※1つの文(ステートメント)を改行する場合は、_(アンダーバー)を使用します

End Sub

シートの複製(コピー)

Copyメソッド

○構文
Worksheet.Copy Before:=/After:=

○処理
指定したワークシートを複製します。

○引数
Before/Afterに既存のSheetオブジェクトを指定すると、指定したシートの前/後に複製します。
Before/Afterを指定しない場合、新規ブックが作成され、そこに複製します。

Sub シートの複製()
    
    '1つ前のシートに複製
    ActiveSheet.Copy Before:=ActiveSheet
    '最後のシートを複製
    Worksheets(Worksheets.Count).Copy After:=Worksheets(Worksheets.Count)
    
    '新規ブックに複製
    Worksheets(1).Copy
    
    '既存の別ブックに複製
    Workbooks(1).Worksheets(1).Copy _
    After:=Workbooks(2).Worksheets(Workbooks(2).Worksheets.Count)
    
End Sub

シートの表示設定

Visibleプロパティ

○構文
<表示状態の取得>
Worksheet.Visible
<表示状態の設定>
Worksheet.Visible = True/False/xlSheetVisibillity

○処理
指定したシートの表示状態の取得・設定をします。
Trueを設定すると表示、Falseを設定すると非表示になります。
xlSheetVisibillity列挙型を指定すると、定数に応じた表示設定ができます。

xlSheetVisibillity内容
xlSheetVisible-1シートを表示する
xlSheetHidden0シートを非表示にする
手動で再表示できる
xlSheetVeryHidden2シートを非表示にする
手動で再表示できないため、表示するにはxlSheetVisibleを設定する必要がある
Sub シートの表示()
        
    'シートを全て表示する
    Dim i As Long '整数型の変数を定義
    For i = 1 To Worksheets.Count 'For Next による繰り返し処理
        Worksheets(i).Visible = xlSheetVisible
    Next i
    
End Sub

コメント